FKERES

A függvény egy tömb első oszlopában keres egy megadott értéket, és az így kapott sorból veszi az oszlop_szám argumentummal kijelölt cellát, és ennek tartalmát adja eredményül.

Az FKERES névben az F a függőleges irányt jelöli. Az FKERES helyett a VKERES függvényt kell használni, ha az összehasonlítási értékek a keresett adatoktól jobbra vagy balra található valamelyik oszlopban helyezkednek el.

Szintaxis

FKERES(keresési_érték;tömb;oszlop_szám;tartományban_keres)

Keresési_érték:  A tömb (tömb: Akkor használjuk, amikor egy képletnek több eredményt kell visszaadnia, illetve ha a függvény sorokban vagy oszlopokban elrendezett argumentumokkal dolgozik. A tömbtartomány olyan cellák tartománya, amelyeknek a képlete közös; a tömbállandó állandók olyan csoportja, amely a képletekben argumentumként használható.) első oszlopában keresendő érték. A keresési_érték lehet érték vagy hivatkozás. Ha a keresési_érték alacsonyabb a tömb első oszlopának legkisebb értékénél, az FKERES a #HIÁNYZIK hibaértéket adja vissza

Tömb:  Két vagy több adatoszlop. Az argumentum megadásakor használjunk tartományra mutató hivatkozást vagy tartománynevet. A függvény a tömb első oszlopában keresi a keresési értéket. Ez az érték lehet szöveg, szám vagy logikai érték. A függvény a kis- és nagybetűk között nem tesz különbséget.

Oszlop_szám:  A tömb azon oszlopának sorszáma, amelyből az eredményt meg kívánjuk kapni. Ha az oszlop_szám értéke 1, akkor a tömb első oszlopában lévő értéket kapjuk eredményül, ha az oszlop_szám értéke 2, akkor a tömb második oszlopában lévő értéket és így tovább. Ha az oszlop_szám értéke

  • egynél kisebb, akkor az FKERES az #ÉRTÉK! hibaértéket adja vissza, ha pedig
  • nagyobb, mint a tömb oszlopainak száma, akkor #HIV! hibaértéket kapunk.

Tartományban_keres:  Logikai érték, amellyel az FKERES függvény pontos vagy közelítő keresését adhatjuk meg:

  • Ha értéke IGAZ vagy hiányzik, a függvény pontos vagy közelítő egyezést ad vissza. Ha pontos egyezést nem talált a függvény, akkor a következő legnagyobb, de a keresési_érték argumentumnál kisebb értéket adja vissza.

    A tömb első oszlopában található értékeket növekvő sorrendben kell elrendezni ahhoz, hogy az FKERES biztosan a megfelelő értéket adja vissza. Az értékek növekvő sorrendbe rendezéséhez válasszuk az Adatok menü Sorba rendezés parancsát, majd az Emelkedő beállítást. További tájékoztatásért olvassuk el az Alapértelmezés szerinti rendezési sorrend című témakört.

  • Ha az argumentum értéke HAMIS, akkor az FKERES pontos egyezést keres. Ebben az esetben a tömb első oszlopának nem szükséges rendezettnek lennie. Ha két vagy több olyan érték is található a tömbben, amely egyezik a keresési értékkel, az elsőként megtalált érték használatos. Ha nem talál pontos egyezést, a függvény a #HIÁNYZIK hibaértéket adja vissza.

Megjegyzések

  • Ha a tömb első oszlopában szöveges értékeket keresünk, győződjünk meg arról, hogy az nem tartalmaz kezdő és záró szóközöket, következetlenül használt egyenes ( ' és " ) vagy hajlított ( ‘ és “) idézőjeleket, illetve nem nyomtatandó karaktereket, ezekben az esetekben ugyanis az FKERES helytelen vagy nem várt értéket adhat vissza. A szöveges adatok megtisztításáról a Szöveg- és adatfüggvények (angol nyelven) című témakörben olvashatunk további részleteket.
  • Szám- vagy szöveges értékek keresésekor fontos, hogy az első oszlop adatai ne szöveges értékként tárolódjanak, ez esetben ugyanis az FKERES helytelen vagy nem várt értéket adhat vissza. További tudnivalókért tanulmányozzuk a Szövegként tárolt számok számmá alakítása című témakört.
  • Ha a tartományban_keres értéke IGAZ, és a keresési_érték szöveg, akkor a keresési_értékben használható a kérdőjel (?) és a csillag (*) mint helyettesítő karakter. A kérdőjel egyetlen tetszőleges karaktert, a csillag tetszőleges karaktersorozatot helyettesít. Ha kérdőjelet vagy csillagot szeretnénk keresni, a karakter elé írjunk egy tilde (~) jelet.

1. példa

A példa könnyebben megérthető, ha üres munkalapra másoljuk.

MegjelenítésEgy példa másolása

  1. Hozzunk létre egy üres munkafüzetet vagy munkalapot.
  2. Jelöljük ki a példát a súgótémakörben.

     Megjegyzés:   Ne jelöljük ki a sor- vagy oszlopfejléceket.

    Példa kijelölése a súgóban

    Példa kijelölése a súgóban
  3. Nyomjuk le a CTRL+C billentyűkombinációt.
  4. A munkalapon jelöljük ki az A1 cellát, és nyomjuk le a CTRL+V billentyűkombinációt.
  5. Az eredmények és az azokat eredményező képletek megjelenítése közötti váltáshoz nyomjuk meg a CTRL+` (fordított ékezet) billentyűkombinációt, vagy kattintsunk a Képletek lap Képletvizsgálat csoportjának Képletek megjelenítése gombjára.

Az alábbi példa a légköri jellemzőket tartalmazó táblázat Sűrűség oszlopának értékei szerint keres a Viszkozitás és Hőmérséklet oszlopban. (Az értékek a tengerszint magasságában lévő 0 Celsius fokos levegőre, vagyis 1 atmoszféra nyomásra vonatkoznak.)

 
1
2
3
4
5
6
7
8
9
10
A B C
Sűrűség Viszkozitás Hőmérséklet
0,457 3,55 500
0,525 3,25 400
0,616 2,93 300
0,675 2,75 250
0,746 2,57 200
0,835 2,38 150
0,946 2,17 100
1,09 1,95 50
1,29 1,71 0
Képlet Leírás (eredmény)
=FKERES(1;A2:C10;2) Közelítő egyezést keres az 1 értékkel az A oszlopban, megtalálja a legmagasabb, de 1-nél még nem nagyobb értéket (0,946), és visszaadja a B oszlop ugyanazon sorban szereplő értékét. (2,17)
=FKERES(1;A2:C10;3;IGAZ) Közelítő egyezést keres az 1 értékkel az A oszlopban, megtalálja a legmagasabb, de 1-nél még nem nagyobb értéket (0,946), és visszaadja a C oszlop ugyanazon sorban szereplő értékét. (100)
=FKERES(0,7;A2:C10;3;HAMIS) Pontos egyezést keres a 0,7 értékkel az A oszlopban. Mivel nem található pontos egyezés az A oszlopban, hibaértéket ad vissza. (#HIÁNYZIK)
=FKERES(0,1;A2:C10;2;IGAZ) Közelítő egyezést keres a 0,1 értékkel az A oszlopban. Mivel a 0,1 alacsonyabb az A oszlopban található legkisebb értéknél, hibaértéket ad vissza. (#HIÁNYZIK)
=FKERES(2;A2:C10;2;IGAZ) Közelítő egyezést keres a 2 értékkel az A oszlopban, megtalálja a legmagasabb, de 2-nél még nem nagyobb értéket (1,29), és visszaadja a B oszlop ugyanazon sorban szereplő értékét. (1,71)

2. példa

A példa könnyebben megérthető, ha üres munkalapra másoljuk.

MegjelenítésEgy példa másolása

  1. Hozzunk létre egy üres munkafüzetet vagy munkalapot.
  2. Jelöljük ki a példát a súgótémakörben.

     Megjegyzés:   Ne jelöljük ki a sor- vagy oszlopfejléceket.

    Példa kijelölése a súgóban

    Példa kijelölése a súgóban
  3. Nyomjuk le a CTRL+C billentyűkombinációt.
  4. A munkalapon jelöljük ki az A1 cellát, és nyomjuk le a CTRL+V billentyűkombinációt.
  5. Az eredmények és az azokat eredményező képletek megjelenítése közötti váltáshoz nyomjuk meg a CTRL+` (fordított ékezet) billentyűkombinációt, vagy kattintsunk a Képletek lap Képletvizsgálat csoportjának Képletek megjelenítése gombjára.

Ez a példa egy csecsemőknek készített árucikkeket tartalmazó táblázat Cikkazonosító oszlopában keres egy adott értéket, és a Költség vagy Haszonkulcs oszlop megfelelő értékét adja vissza az árak és próbafeltételek számításához.

 
1
2
3
4
5
6
A B CD
Cikkazonosító Árucikk Költség Haszonkulcs
KO-340 Babakocsi $145,67 30%
PA-567 Partedli $3,56 40%
PE-328 Pelenka $21,45 35%
TO-989 Törlőkendő $5,12 40%
OR-469 Orrszívó $2,56 45%
Képlet Leírás (eredmény)
= FKERES("PE-328"; A2:D6; 3; HAMIS) * (1 + FKERES("PE-328"; A2:D6; 4; HAMIS)) Kiszámítja a pelenka kiskereskedelmi árát a haszonkulcs mértékének megfelelően megnövelve a költségértéket. ($28,96)
= (FKERES("TO-989"; A2:D6; 3; HAMIS) * (1 + FKERES("TO-989"; A2:D6; 4; HAMIS))) * (1 - 20%) Kiszámítja a törlőkendők értékesítési árát levonva a megadott kedvezményt a kiskereskedelmi árból. ($5,73)
= HA(FKERES(A2; A2:D6; 3; HAMIS) >= 20; "A haszonkulcs " & 100 * FKERES(A2; A2:D6; 4; HAMIS) &"%"; "A költség 20 dollárnál kisebb") Ha egy árucikk költsége legalább 20 dollár, megjeleníti "A haszonkulcs nn%" karakterláncot; egyébként "A költség 20 dollárnál kisebb" karakterláncot jeleníti meg. (A haszonkulcs 30%)
= HA(FKERES(A3; A2:D6; 3; HAMIS) >= 20; "A haszonkulcs " & 100 * FKERES(A3; A2:D6; 4; HAMIS) &"%"; "A költség $" & FKERES(A3; A2:D6; 3; HAMIS)) Ha egy árucikk költsége legalább 20 dollár, megjeleníti "A haszonkulcs nn%" karakterláncot; egyébként "A költség $" karakterláncot jeleníti meg. (A költség $3,56)

3. példa

A példa könnyebben megérthető, ha üres munkalapra másoljuk.

MegjelenítésEgy példa másolása

  1. Hozzunk létre egy üres munkafüzetet vagy munkalapot.
  2. Jelöljük ki a példát a súgótémakörben.

     Megjegyzés:   Ne jelöljük ki a sor- vagy oszlopfejléceket.

    Példa kijelölése a súgóban

    Példa kijelölése a súgóban
  3. Nyomjuk le a CTRL+C billentyűkombinációt.
  4. A munkalapon jelöljük ki az A1 cellát, és nyomjuk le a CTRL+V billentyűkombinációt.
  5. Az eredmények és az azokat eredményező képletek megjelenítése közötti váltáshoz nyomjuk meg a CTRL+` (fordított ékezet) billentyűkombinációt, vagy kattintsunk a Képletek lap Képletvizsgálat csoportjának Képletek megjelenítése gombjára.

Ez a példa az alkalmazottak táblázatában keres egy adott azonosítót, és a többi oszlop megfelelő értékei alapján kiszámítja az alkalmazottak korát és kockázati tényezőit.

 
1
2
3
4
5
6
7
A B CDE
Azonosító Vezetéknév Keresztnév BeosztásSzületési dátum
1 Dobándi BarbaraÜzletkötő 1968.12.08.
2 Fischer PéterAlelnök, értékesítés1952.02.19.
3 Lukács EszterÜzletkötő 1963.08.30.
4 Pék MargitÜzletkötő 1958.09.19.
5 Budai PéterÉrtékesítési vezető 1955.03.04.
6 Sárközi MiklósÜzletkötő 1963.07.02.
Képlet Leírás (eredmény)
=INT(YEARFRAC(DÁTUM(2004;6;30); FKERES(5;A2:E7;5; HAMIS); 1)) Megkeresi az 5-ös azonosítójú alkalmazott korát a 2004-es pénzügyi évben. A YEARFRAC függvény segítségével kivonja a születésnap dátumát a pénzügyi év végének dátumából, és az INT függvény használatával egész számra kerekítve megjeleníti az eredményt. (49)
=HA(NINCS(FKERES(5;A2:E7;2;HAMIS)) = IGAZ; "Nincs ilyen alkalmazott"; FKERES(5;A2:E7;2;HAMIS)) Ha található 5-ös azonosítójú alkalmazott a táblázatban, megjeleníti a vezetéknevét; egyébként a „Nincs ilyen alkalmazott” üzenetet jeleníti meg. (Budai)

A NINCS függvény IGAZ értéket ad vissza, ha az FKERES függvény #HIÁNYZIK hibát jelez.

=HA(NINCS(FKERES(15;A3:E8;2;HAMIS)) = IGAZ; "Nincs ilyen alkalmazott"; FKERES(15;A3:E8;2;HAMIS)) Ha található 15-ös azonosítójú alkalmazott a táblázatban, megjeleníti a vezetéknevét; egyébként a „Nincs ilyen alkalmazott” üzenetet jeleníti meg. (Nincs ilyen alkalmazott)

A NINCS függvény IGAZ értéket ad vissza, ha az FKERES függvény #HIÁNYZIK hibát jelez.

=FKERES(4;A2:E7;2;HAMIS) & " " & FKERES(4;A2:E7;3;HAMIS) & " beosztása " & FKERES(4;A2:E7;4;HAMIS) & "." A 4-es azonosítójú alkalmazott adatait tartalmazó három cella értékét összefűzi egy mondattá. (Pék Margit beosztása üzletkötő.)

 Megjegyzés:   A fenti példában az első képlet a YEARFRAC függvényt alkalmazza. Ha a függvény nem érhető el, és helyette a program a #NÉV? hibát jeleníti meg, telepítsük és töltsük be az Analysis ToolPak bővítményt.

MegjelenítésHogyan?

  1. Az Eszközök menüben kattintsunk a Bővítménykezelő parancsra.
  2. A Létező bővítmények listában jelöljük be az Analysis ToolPak elem melletti jelölőnégyzetet, és kattintsunk az OK gombra.
  3. Szükség esetén kövessük a telepítő utasításait.
Lásd még
Lásd még